alias kickle { .timer 1 10 kkk $1- }
alias kkk { swhbot mode $1 +b $2 | swhbot kick $1 $2 Voice'niz alındıktan sonra $kp($1) kanalın'da 10 saniye beklediniz. Hoş sohbetler. } 
alias yuzde { return $+(%,$left($calc($hget($1,$2)*100/$hget($3,$4)),4)) }
alias cvp { swhbot $1- }
alias kp { return $+($chr(40),$chr(2),$1-,$chr(2),$chr(41)) }
alias ayr { return $remove($gettok($1-,1,33),$chr(58)) }
alias oks { $+(.timer,knotr) 1 1 kntrl $1- }
alias kntrl {
  if !$hmatch(helplist,$1) && $1 != $_hbot { swhbot userip $1 } 
  else { 
    .hinc -m ygiris $1 1 | .hsave -i ygiris ygiris.db | .hinc -m ygiris y 1 | .hsave -i ygiris ygiris.db
    swhbot privmsg $1 $_help kanalına hoşgeldiniz. Bot tarafından helper(yardımcı) olarak algılandınız.
    swhbot privmsg $1 Bugüne kadar $kp($_help) kanalına; $kp($hget(ygiris,$1)) defa giriş yaptınız. |  swhbot privmsg $1 Hayırlı görevler.
    if !$isdir(helper) { mkdir helper } | else { write $+(helper/,$1,.txt) => Giriş: $kp($date) - Saat: $kp($time) }
  }
}
on *:start: {
  if $isfile(kanal.db) { hmake kanal 100 | hload -i kanal kanal.db } | else { hmake kanal 100 | hsave -i kanal kanal.db } 
  if $isfile(helplist.db) { hmake helplist 100 | hload -i helplist helplist.db } | else { hmake helplist 100 | hsave -i helplist helplist.db } 
  if $isfile(ygiris.db) { hmake ygiris 100 | hload -i ygiris ygiris.db } | else { hmake ygiris 100 | hsave -i ygiris ygiris.db } 
  if $isfile(ipler.db) { hmake ipler 100 | hload -i ipler ipler.db } | else { hmake ipler 100 | hsave -i ipler ipler.db } 
  if $isfile(tvoice.db) { hmake tvoice 100 | hload -i tvoice tvoice.db } | else { hmake tvoice 100 | hsave -i tvoice tvoice.db } 
  if $isfile(voice.db) { hmake voice 100 | hload -i voice tvoice.db } | else { hmake voice 100 | hsave -i voice voice.db } 
  if $isfile(banlar.db) { hmake banlar 100 | hload -i banlar banlar.db } | else { hmake banlar 100 | hsave -i banlar banlar.db } 
  if $isfile(text.db) { hmake text 100 | hload -i text text.db } | else { hmake text 100 | hsave -i text text.db }   
  if $isfile(ycıkıs.db) { hmake ycıkıs 100 | hload -i ycıkıs ycıkıs.db } | else { hmake ycıkıs 100 | hsave -i ycıkıs ycıkıs.db } 
}

alias swhbot if ($sock(hbot).status == active) sockwrite -n hbot $1-
on *:sockclose:hbot:{ $+(.timer,hbot) 1 2 sockopen hbot $_sunucuip $_port }
on *:sockopen:hbot:{
  if ($sockerr) { sockclose hbot | $+(.timer,hbot) 1 2 sockopen hbot $_sunucuip $_port | returnex }
  swhbot NICK $+($_hbot,$r(10,9999)) 
  swhbot USER $_ident "" " $+ $iif($host,$host,$ip) $_username
  sockmark $sockname $_hbot
}
on *:sockread:hbot:{
  if ($sockerr) { sockclose hbot | $+(.timer,hbot) 1 2 sockopen hbot $_sunucuip $_port | returnex }
  var %; | sockread %; | tokenize 32 %;
  if ($1 = ping) swhbot pong $remove($2,:) 
  if ($2 == 001) {
    swhbot oper $_oper
    swhbot join 0,0
    swhbot nick $_hbot
    swhbot chghost $_hbot $_host
  }
  if $1 == error && $2 == :closing { sockclose hbot | $+(.timer,hbot) 1 2 sockopen hbot $_sunucuip $_port }  
  if ($2 == 451) { sockclose hbot | $+(.timer,hbot) 1 4 sockopen hbot $_sunucuip $_port }  
  if ($regex($2,/473|475|471|474)) { swhbot sajoin $_hbot $4 }
  if ($regex($2,/481|411)) { swhbot oper $_oper | swhbot nick $_hbot | swhbot nickserv identify $_pass | swhbot os su $_supass }
  if $2 == 433 { swhbot ns ghost $_hbot $_pass | swhbot ns release $_hbot $_pass | swhbot nick $_hbot }
  if $2 == PRIVMSG || $2 == NOTICE || $2 == ACTION && $left($3,1) != $chr(35) {
    if $4 == :TIME { swhbot NOTICE $_nick($1)  TIME $time | return }
    if $4 == :VERSION { swhbot NOTICE $_nick($1) VERSION 2mIRC v6.35 Khaled Mardam-Bey | swhbot NOTICE $_nick($1) VERSION $_username | return }
    if $4 == :FINGER { swhbot NOTICE $_nick($1) FINGER $_username $+  ( $+ $_ident $+ @) Idle 1 seconds | return }
    if $4 == :PING  { swhbot NOTICE $_nick($1) PONG $5- | return }
  }
  if ($2 == NICK) { 
    if $_nick($1) == $_hbot { swhbot ns ghost $_hbot $_pass | swhbot ns release $_hbot $_pass | $+(.timer,$rand(100,999)) 1 3 swhbot nick $_hbot }
    if $right($3,-1) == $_hbot {
      swhbot nickserv identify $_pass
      swhbot oper $_oper
      $iif($_supass,swhbot os su $_supass)
      swhbot join 0,0
      swhbot mode $right($3,-1) +qHp-h
      swhbot chghost $right($3,-1) $_host
      $+(.timer,hbotgirs) 1 3 swhbot sajoin $right($3,-1) $+($_bots,$chr(44),$_help,$chr(44),$_helpers)
    }
  }
  if $2 == 366 { if !$istok($_bots $_help $_helpers,$4,32) { swhbot part $4 } }  
  if $2 == PART { if $_nick($1) == $_hbot { if $istok($_log $_bots $_help $_helpers,$3,32) { swhbot sajoin $_nick($1) $3 } } }
  if ($2 == KICK) {
    if $4 == $_hbot {
      if $istok(ChanServ NickServ MemoServ HelpServ OperServ StatServ,$1,32) { swhbot sajoin $4 $3 | return }
      swhbot os raw :chanserv mode $3 -qaoh+v $_nick($1) $_nick($1) $_nick($1) $_nick($1) $_nick($1) 
      swhbot sajoin $4 $3
      return 
    } 
  }
  if ($2 == JOIN) {
    if $istok($_bots $_help $_helpers,$right($3,-1),32) && $_nick($1) == $_hbot {
      swhbot mode $right($3,-1) -qao+h $_nick($1) $_nick($1) $_nick($1) $_nick($1)
      swhbot chghost $right($3,-1) $_host
      swhbot os raw svsmode $_nick($1) +qHpN-h
      return
    }
    if $remove($3,:) == $_help {
      if $regex($gettok($1,2,64),/( $+ $_host $+ |Network|Server|Root|admin|ircop|oper|services|techinal|services)/i) { return }
      oks $_nick($1) | if $hget(tarih) { hinc -m tarih $date 1 | hsave -i tarih tarih.db } 
    }
    if $remove($3,:) == $_helpers {
      cvp privmsg $ayr($1) $kp($ayr($1)) Hoşgeldiniz.
      cvp privmsg $ayr($1) $kp($_help) kanal'ı istatistikleri için; $kp($_helpers) kanalına $kp(!istatistik) yazınız.  
      cvp privmsg $ayr($1) Listede ekli olan helper'ler'i görmek için; $kp(!helperler) yazınız.
      cvp privmsg $ayr($1) Helper listesine helper eklemek için; $kp(!hekle helper-nick) yazınız.
      cvp privmsg $ayr($1) $kp($_help) kanalın'da bugün verilen voice sayısı ve nick'leri görmek için; $kp($_helpers) kanalına $kp(!voicelist) yazınız.
      cvp privmsg $ayr($1) $kp($_help) kanalın'da atılan toplam ban sayısı ve nickler için; $kp($_helpers) kanalına $kp(!banlar) yazınız.
      cvp privmsg $ayr($1) Bir helper hakkında detaylı bilgi almak için; $kp($_helpers) kanalına $kp(!bilgi helper-nick) yazınız.
      cvp privmsg $ayr($1) Şuan'da $kp($_help) kanal'ında bulunup away(meşgul) olan nick'leri görmek için; $kp($_helpers) kanalına $kp(!awaylist) yazınız.
      cvp privmsg $ayr($1) $kp($_helpers) kanal'ındaki helper'lerin idle sürelerini görmek için; $kp(!idlelist) yazınız.
      cvp privmsg $ayr($1) $kp($_help) kanalı'na devamlı giriş yapan ve koyduğunuz limit'i aşarak banlanan, ip'leri görmek için; $kp($_helpers) kanalına $kp(!floodip) yazınız.
    }
  }
  if $2 == MODE && $left($3,1) == $chr(35) {
    if (!$5) { return }
    if ($regex($4,\+(b))) && ($+(*,$_hbot,*) iswm $5-) { swhbot mode $3 -b $_hbot | return }
    if ($regex($4,\-(h))) && ($+(*,$_hbot,*) iswm $5-) { swhbot mode $3 -qao+h $_hbot $_hbot $_hbot $_hbot }
    if ($regex($4,\+(a|o|q))) && ($+(*,$_hbot,*) iswm $5-) { swhbot mode $3 -qao+h $_hbot $_hbot $_hbot $_hbot }
    if $4 == +v && $hmatch(helplist,$ayr($1)) {
      .hinc -m tvoice v 1 | hsave -i tvoice tvoice.db
      .hinc -m voice $ayr($1) 1 | hsave -i voice voice.db
      .hinc -m $+(voices,$replace($date,/,.)) $ayr($1) 1 | hsave -i $+(voices,$replace($date,/,.)) $+(voices,$replace($date,/,.),.db)
      .hinc -m $+(voices,$replace($date,/,.)) $date 1 | hsave -i $+(voices,$replace($date,/,.)) $+(voices,$replace($date,/,.),.db)
      cvp privmsg $_helpers $kp($_help) bilgi: $kp($ayr($1)) helper'i; $kp($5) rumuzuna voice verdi.
    }
    if $left($4,1) == + && $count($4,b) >= 1 && $hmatch(helplist,$ayr($1)) {
      hinc -m banlar v $count($4,b) | hsave -i banlar banlar.db 
      if $hget(banlar,$ayr($1)) { hinc -m banlar $ayr($1) $count($4,b) | hsave -i banlar banlar.db }
      else { hadd -m banlar $ayr($1) $count($4,b) | hsave -i banlar banlar.db }
    }
  }
  if $2 == 317 && %idles == on  {
    cvp privmsg $_helpers Nick: $kp($4) - Idle süresi: $kp($replace($duration($5),secs,$+($chr(32),sn),mins,$+($chr(32),dk),hrs,$+($chr(32),saat))) - Bağlandığı zaman: $kp($asctime($6,dd/mm/yy - hh:nn:ss))
  }
  if $2 == 352 && $3 == $sock(hbot).mark {
    if $4 == $_helpers { if G !isin $9 { .hadd -m online $8 1 } }
    if $4 == $_help { 
      if G isin $9 { 
        .hadd -m offline $8 1
        .timer 1 3 cvp privmsg $_helpers $+(4,$8,) Away olduğu için $_help kanalından çıkarıldı.
        swhbot sapart $8 $_help
        swhbot privmsg $8 :Away olduğunuz için4 $_help kanalından çıkarıldınız.
      } 
    }
  }
  if $2 == 353 && $5 == $_helpers && %idles  { set %idle $remove($6-,~,%,@,&,+,.,:) }
  if $2 == 366 && $4 == $_helpers && %idle { 
    var %& = 1,%2 = $numtok(%idle,32) | while %& <= %2 { cvp whois $gettok(%idle,%&,32) | inc %& } 
  }
  if $2 == 315 && %idles {
    if $4 == $_helpers { var %y = 1,%yy = $hget(online,0).item,%yyy | while %y <= %yy { if $hget(online,%y).item != $sock(hbot).mark {  %yyy = $addtok(%yyy,$hget(online,%y).item,32) } | inc %y }
      cvp privmsg $_helpers Online olan helper'lar; $kp($iif(%yyy,%yyy,Online helper yok.)) sorunlu kullanıcı ile igilenin. | $iif($hget(online),hfree online)
    }
    if $4 == $_help { 
      var %of = 1,%off = $hget(offline,0).item,%offf | while %of <= %off { 
        %offf = $addtok(%offf,$hget(offline,%of).item,32)
        inc %of
      }
      cvp privmsg $_helpers Away durumunda olan nickler; $kp($iif(%offf,%offf,YOK))
      cvp privmsg $_helpers -
      cvp privmsg $_helpers $kp($_help) kanalın'da bulunup, away durumunda olan nickler sıralandı. 
      $iif($hget(offline),hfree offline)
    }
  }
  if $2 == 340 { 
    cvp who $_helpers
    if $hmatch(ipler,$+($date,½,$gettok($gettok($remove($4,$chr(58)),2,43),2,64))) { hinc -m ipler $+($date,½,$gettok($gettok($remove($4,$chr(58)),2,43),2,64)) 1 } 
    else { hadd -m ipler $+($date,½,$gettok($gettok($remove($4,$chr(58)),2,43),2,64)) 1 }
    cvp privmsg $_helpers Bilgi: $_help kanalı'na, $kp($remove($gettok($4,1,61),$chr(58),$chr(42))) nick'i girdi. - Ident: $kp($gettok($gettok($4,2,43),1,64)) - IP: $kp($gettok($gettok($remove($4,$chr(58)),2,43),2,64)) - Bu IP adres'den bugün: $kp($hget(ipler,$+($date,½,$gettok($gettok($remove($4,$chr(58)),2,43),2,64)))) defa giriş yapıldı.
    if $hget(ipler,$+($date,½,$gettok($gettok($remove($4,$chr(58)),2,43),2,64))) >= 5 { 
      cvp mode $_help +b $remove($gettok($4,1,61),$chr(58),$chr(42))
      cvp kick $_help $remove($gettok($4,1,61),$chr(58),$chr(42)) Bu IP adresin'den $+ $kp($gettok($gettok($remove($4,$chr(58)),2,43),2,64))) $+(bugün,$kp($date),;) $kp($hget(ipler,$+($date,½,$gettok($gettok($remove($4,$chr(58)),2,43),2,64)))) defa giriş yapıldı. 
      cvp cs akick $_help add $+($remove($gettok($4,1,61),$chr(58),$chr(42)),!*@*) IP Flood. $_hbot
      .hdel ipler $+($date,½,$gettok($gettok($remove($4,$chr(58)),2,43),2,64))) 
      .hadd -m flood $gettok($gettok($remove($4,$chr(58)),2,43),2,64) $remove($gettok($4,1,61),$chr(58),$chr(42))
      .hsave -i flood flood.db
      return
    } 
    cvp privmsg $_helpers $kp($_help) UYARI: Sorunlu user $+ $kp($remove($gettok($4,1,61),$chr(58),$chr(42))) şuan'da yardım beklemekte.
    cvp privmsg $remove($gettok($4,1,61),$chr(58),$chr(42)) $kp($remove($gettok($4,1,61),$chr(58),$chr(42))) Resmi IRC/d-Service(s) yardım kanalı olan, $kp($_help) kanalı'na hoşgeldiniz.
    cvp privmsg $remove($gettok($4,1,61),$chr(58),$chr(42)) Kanal'da sadece IRC/d-Service(s) hakkında yardım verilmektedir.
    cvp privmsg $remove($gettok($4,1,61),$chr(58),$chr(42)) Ip adresiniz; $kp($gettok($gettok($remove($4,$chr(58)),2,43),2,64)) kayıt edildi. Bugün bu IP adresinden; $kp($hget(ipler,$+($date,½,$gettok($gettok($remove($4,$chr(58)),2,43),2,64)))) defa giriş yaptınız.
    cvp privmsg $remove($gettok($4,1,61),$chr(58),$chr(42)) Uyarı: Bu ip adresinden, bugün $+ $kp($date) $kp($calc(%limit - $hget(ipler,$+($date,½,$gettok($gettok($remove($4,$chr(58)),2,43),2,64))))) defa giriş yapabilme hakkınız kaldı.
    cvp privmsg $remove($gettok($4,1,61),$chr(58),$chr(42)) -
    cvp privmsg $remove($gettok($4,1,61),$chr(58),$chr(42)) Eğer $kp($_help) kanal'ında online yetkili yok ise, özelime; $kp(!destek) yazınız.
  }
  if $2 == privmsg && $3 == $_helpers {
    if $remove($4,$chr(58)) == !komutlar {
      cvp privmsg $3 $kp($_help) kanal'ı istatistikleri için; $kp($_helpers) kanalına $kp(!istatistik) yazınız.  
      cvp privmsg $3 Listede ekli olan helper'ler'i görmek için; $kp(!helperler) yazınız.
      cvp privmsg $3 Helper listesine helper eklemek için; $kp(!hekle helper-nick) yazınız.
      cvp privmsg $3 $kp($_help) kanalın'da bugün verilen voice sayısı ve nick'leri görmek için; $kp($_helpers) kanalına $kp(!voicelist) yazınız.
      cvp privmsg $3 $kp($_help) kanalın'da atılan toplam ban sayısı ve nickler için; $kp($_helpers) kanalına $kp(!banlar) yazınız.
      cvp privmsg $3 Bir helper hakkında detaylı bilgi almak için; $kp($_helpers) kanalına $kp(!bilgi helper-nick) yazınız.
      cvp privmsg $3 Şuan'da $kp($_help) kanal'ında bulunup away(meşgul) olan nick'leri görmek için; $kp($_helpers) kanalına $kp(!awaylist) yazınız.
      cvp privmsg $3 $kp($_helpers) kanal'ındaki helper'lerin idle sürelerini görmek için; $kp(!idlelist) yazınız.
      cvp privmsg $3 $kp($_help) kanalı'na devamlı giriş yapan ve koyduğunuz limit'i aşarak banlanan, ip'leri görmek için; $kp($_helpers) kanalına $kp(!floodip) yazınız.
    }
    if $remove($4,$chr(58)) == !voicelist {
      if !$hget(tvoice,v) { cvp privmsg $3 Herhangi bir voice kaydı bulunamadı. | halt }
      cvp privmsg $3 $kp($_help) kanalı için, voice istatistikleri sıralanıyor.
      cvp privmsg $3 Kayıt tarihinden beri, toplam verilen voice sayısı: $kp($hget(tvoice,v))
      cvp privmsg $3 -
      var %& = 1,%&& = $hget(voice,0).item
      while %& <= %&& {
        if $hget(voice,%&).item != v {
          cvp privmsg $3 Nick: $kp($hget(voice,%&).item) - Verdiği voice sayısı: $kp($hget(voice,%&).data - $yuzde(voice,$hget(voice,%&).item,tvoice,v))
        }
        inc %&
      }
      cvp privmsg $3 - | cvp privmsg $3 Voice listesi sıralanmıştır.
      cvp privmsg $3 Listelenen voice sayacları, bot kuruluş tarihinden beri kayıt altına alınan verilerdir.
      cvp privmsg $3 Voice listesini komple silmek için; $kp(!vsil $date) yazınız.
      cvp privmsg $3 Sadece bugün'e ait voiceler'i listelemek için; $kp(!bvoicelist) yazınız.
    }
    if $remove($4,$chr(58)) == !bvoicelist && !$5- {
      if !$hget($+(voices,$replace($date,/,.)),$date) { cvp privmsg $3 $kp($date) tarihinde verilen voice yok. | halt }
      cvp privmsg $3 $kp($date) tarihinde verilen toplam voice sayısı; $kp($hget($+(voices,$replace($date,/,.)),$date))
      cvp privmsg $3 - | cvp privmsg $3 Nickler sıralanıyor. | cvp privmsg $3 -
      var %/ = 1,%// = $hget($+(voices,$replace($date,/,.)),0).item
      while %/ <= %// {
        if $hget($+(voices,$replace($date,/,.)),%/).item != $date {
          cvp privmsg $3 Nick: $kp($hget($+(voices,$replace($date,/,.)),%/).item) - Verdiği voice sayısı: $kp($hget($+(voices,$replace($date,/,.)),%/).data)
        }
        inc %/
      }
      cvp privmsg $3 - | cvp privmsg $3 $kp($date) tarihide verilen tüm voice'lar sıralanmıştır.
      cvp privmsg $3 Daha önceki tarihler'deki, voice'leri sıralamak için; $kp(!vlist GG/AA/YY) yapınız. Örnek: $kp(!vlist $date)
      cvp privmsg $3 Kaç adet voice listesinin bulunduğunu öğrenmek için; $kp(!vclist) yazınız.
    }
    if $remove($4,$chr(58)) == !vlist && !$6- {
      if !$5 || $regex($5,[1-9]) == 0 { cvp privmsg $3 Yanlış kullanım. Kullanım şekli: $kp(!vlist GG/AA/YY) - Örnek: $kp(!vlist $date) | halt }
      else { 
        if !$isfile($+(voices,$replace($5,/,.),.db)) { cvp privmsg $3 $kp($5) tarihin'de voice verilmemiş. Veya liste oluşturulmamış. Varolmayan bir tarih girmiş'de olabilirsiniz. | halt }
        else { 
          if !$hget($+(voices,$replace($5,/,.))) { hmake $+(voices,$replace($5,/,.)) 100 | hload -i $+(voices,$replace($5,/,.)) $+(voices,$replace($5,/,.),.db) }
          cvp privmsg $3 $kp($5) tarihinde'ki voice listesi sıralanıyor.
          cvp privmsg $3 $kp($5) tarihinde verilen toplam voice sayısı; $kp($hget($+(voices,$replace($5,/,.)),$5))
          cvp privmsg $3 -
          var %2 = 1,%22 = $hget($+(voices,$replace($5,/,.)),0).item
          while %2 <= %22 {
            if $hget($+(voices,$replace($5,/,.)),%2).item != $5 {
              cvp privmsg $3 Nick: $kp($hget($+(voices,$replace($5,/,.)),%2).item) - Verdiği voice sayısı: $kp($hget($+(voices,$replace($5,/,.)),%2).data)
            }
            inc %2
          }
          cvp privmsg $3 - | cvp privmsg $3 Kayıtlar sıralandı. | cvp privmsg $3 Bu kayıt'ı silmek için; $kp(!vsil $5) yazınız.
        }
      }
    }
    if $remove($4,$chr(58)) == !vsil && $5 && !$6- {
      if $5 == $date { cvp privmsg $_helpers Bugüne ait olan verileri silemezsiniz. | halt }
      if !$5 || $regex($5,[1-9]) == 0 { cvp privmsg $_helpers Yanlış kullanım. Kullanım şekli: $kp(!vsil GG/AA/YY) - Örnek: $kp(!vsil $date) | halt }
      else { 
        if !$isfile($+(voices,$replace($5,/,.))) { cvp privmsg $_helpers $kp($5) Tarihine ait bir veri bulunamadı. | halt }
        else { hfree $+(voices,$replace($5,/,.)) | remove $+(voices,$replace($5,/,.),.db) | cvp privmsg $_helpers $kp($5) tarihine ait olan veriler tamamen silindi. } 
      }
    }
    if $remove($4,$chr(58)) == !vclist && !$5- {
      if $findfile($mircdir,voices*,0) == 0 { cvp privmsg $_helpers Herhangi bir voice listesi bulunamadı. | halt }
      else { 
        cvp privmsg $_helpers Tüm voice listeleri sıralanıyor;
        cvp privmsg $_helpers Bulunan liste sayısı; $findfile($mircdir,voices*,0) | cvp privmsg $_helpers -
        var %t = 1,%tt = $findfile($mircdir,voices*,0) | while %t <= %tt { 
          cvp privmsg $_helpers Liste $+(%t,:) $kp($replace($remove($nopath($findfile($mircdir,voices*,%t)),voices,.db),.,/)) - Listeyi görmek için; $kp(!vlist $replace($remove($nopath($findfile($mircdir,voices*,%t)),voices,.db),.,/)) yazınız.
          inc %t
        }
        cvp privmsg $_helpers - | cvp privmsg $_helpers Listeler sıralandı.
        cvp privmsg $_helpers Liste'lerden herhangi birisini silmek için; ÖRNEKTİR: $kp(!vsil $date) yazınız.
      }
    }
    if $remove($4,$chr(58)) == !banlar && !$5- {
      if !$hmatch(banlar,v) { cvp privmsg $_helpers $kp($_help) için, ban kaydı bulunamadı. | halt }
      else {
        cvp privmsg $_helpers $kp($_help) için ban kayıtları sıralanıyor.
        cvp privmsg $_helpers Toplam atılan ban sayısı: $kp($hget(banlar,v)) | cvp privmsg $_helpers Nickler sıralanıyor; | cvp privmsg $_helpers -
        var %u = 1,%uu = $hget(banlar,0).item
        while %u <= %uu {
          if $hget(banlar,%u).item != v {
            cvp privmsg $_helpers Nick: $kp($hget(banlar,%u).item) - Attığı ban sayısı: $kp($hget(banlar,%u).data - $yuzde(banlar,$hget(banlar,%u).item,banlar,v))
          }
          inc %u
        }
        cvp privmsg $_helpers -
        cvp privmsg $_helpers Tüm ban kayıtları sıralandı.
        cvp privmsg $_helpers Listeyi sıfırlamak için; $kp(!silban) yazınız. (Dikkat: Bugüne kadar kayıt edilen, tüm ban kayıtları silinecektir.)
      }
    }
    if $remove($4,$chr(58)) == !helperler && !$5- {
      if !$hget(helplist) { 
        cvp privmsg $_helpers $kp($_help) kanal'ı için helper listesi boş. 
        cvp privmsg $_helpers Helper eklemek için; $kp(!hekle helper-nick-i) yazınız. | halt 
      }     
      else { 
        cvp privmsg $_helpers Bot'a kayıt ettiğiniz tüm helper'ler sıralanıyor; 
        cvp privmsg $_helpers Kayıtlı olan helper sayısı; $kp($hget(helplist,0).item) | cvp privmsg $_helpers -
        var %1 = 1,%2 = $hget(helplist,0).item | while %1 <= %2 { 
          cvp privmsg $_helpers Helper: $kp($hget(helplist,%1).item)
          inc %1
        }
        cvp privmsg $_helpers - | cvp privmsg $_helpers Kayıtlı olan tüm helper'ler sıralandı.
        cvp privmsg $_helpers Listeye helper eklemek için; $kp(!hekle helper-nick) yazınız.
        cvp privmsg $_helpers Listeden helper silmek için; $kp(!hsil helper-nick) yazınız.
      }
    }
    if $remove($4,$chr(58)) == !silban && !$5- {
      if !$hget(banlar) { cvp privmsg $_helpers Herhangi bir ban kaydı bulunamadı. | halt }
      else { hfree banlar | remove banlar.db | cvp privmsg $_helpers Tüm ban kayıtları sıfırlandı. }
    }
    if $remove($4,$chr(58)) == !bilgi && $5 && !$6- {
      if !$hmatch(helplist,$5) { cvp privmsg $_helpers $kp($5) helper'i hakkında ayrıntılı bilgi bulunamadı. (Bot helper'i tanımamış olabilir. Veya yazdığınız rumuz helper olmayabilir.) | halt }
      else { 
        cvp privmsg $_helpers $kp($5) helper'i hakkında istatistik bilgileri sıralanıyor; | cvp privmsg $_helpers -
        cvp privmsg $_helpers Verdiği toplam voice sayısı: $kp($iif($hget(voice,$5),$hget(voice,$5) - $yuzde(voice,$5,tvoice,v),0)) 
        cvp privmsg $_helpers Attığı toplam ban sayısı: $kp($iif($hget(banlar,$5),$hget(banlar,$5) - $yuzde(banlar,$5,banlar,v),0))
        cvp privmsg $_helpers $kp($_help) kanal'ına giriş sayısı: $kp($iif($hget(ygiris,$5),$hget(ygiris,$5) - $yuzde(ygiris,$5,ygiris,y),0))
        cvp privmsg $_helpers $kp($_help) kanal'ından çıkış sayısı : $kp($iif($hget(ycıkıs,$5),$hget(ycıkıs,$5) - $yuzde(ycıkıs,$5,ycıkıs,y),0))
        cvp privmsg $_helpers $kp($_help) kanalın'da yazdığı satır sayısı: $kp($iif($hget(text,$5),$hget(text,$5) - $yuzde(text,$5,text,t),0))
        cvp privmsg $_helpers -
        cvp privmsg $_helpers $kp($5) Helper'i hakkında istatistikler sıralandı.
        cvp privmsg $_helpers $kp($5) Helper'inin hangi tarihlerde giriş çıkış yaptığın öğrenmek için; $kp(!giris $5) yazınız.
      }
    }
    if $remove($4,$chr(58)) == !giris && $5 && !$6- {
      if !$isfile($+(helper/,$5,.txt)) { cvp privmsg $_helpers $kp($5) Helper'i hakkında, giriş/çıkış istatistikleri bulunamadı. | halt }
      else { 
        cvp privmsg $_helpers $kp($5) Helper'i bugüne kadar $kp($_help) kanalına; $kp($hget(ygiris,$5)) defa giriş - $kp($hget(ycıkıs,$5)) çıkış  yaptı.
        cvp privmsg $_helpers Tarihler listeleniyor. | cvp privmsg $_helpers -
        var %b = 1,%bb = $lines($+(helper/,$5,.txt)) | while %b <= %bb {
          cvp privmsg $_helpers $read($+(helper/,$5,.txt),%b)
          inc %b
        }
        cvp privmsg $_helpers - | cvp privmsg $_helpers $kp($5) Helper'inin giriş/çıkış istatistikleri listelendi.
        cvp privmsg $_helpers Bu verileri silmek için; $kp(!gsil $5) yazınız.
      }
    }
    if $remove($4,$chr(58)) == !gsil && $5 && !$6- {
      if !$isfile($+(helper/,$5,.txt)) { cvp privmsg $_helpers $kp($5) helper'i için silinecek giriş/çıkış istatistikleri bulunamadı. | halt }
      else { remove $+(helper/,$5,.txt) | cvp privmsg $_helpers $kp($5) helper'inin tüm giriş/çıkış kayıtları silindi. }
    }
    if $remove($4,$chr(58)) == !awaylist && !$5- {
      cvp who $_help 
      cvp privmsg $_helpers $kp($_help) kanalın'da bulunan ve away konumun'da olan nick'ler sıralanıyor. 
      cvp privmsg $_helpers - 
    }
    if $remove($4,$chr(58)) == !idlelist && !$5- { 
      .set %idles on | cvp privmsg $_helpers $kp($_helpers) kanalında'ki tüm helper'lerin idle süreleri sıralanıyor. | cvp privmsg $_helpers - | cvp names $_helpers
    }
    if $remove($4,$chr(58)) == !istatistik && !$5- {
      cvp privmsg $_helpers $kp($_help) kanal'ı için tüm istatistikler sıralanıyor; | cvp privmsg $_helpers -
      cvp privmsg $_helpers Toplam verilen voice sayısı: $kp($iif($hget(tvoice,v),$hget(tvoice,v),0))
      cvp privmsg $_helpers Toplam atılan ban sayısı: $kp($iif($hget(banlar,v),$hget(banlar,v),0))
      cvp privmsg $_helpers Toplam yetkili girişi: $kp($iif($hget(ygiris,y),$hget(ygiris,y),0))
      cvp privmsg $_helpers Toplam yetkili çıkışı: $kp($iif($hget(ycıkıs,y),$hget(ycıkıs,y),0))
      cvp privmsg $_helpers Toplam yetkili yazısı: $kp($iif($hget(text,t),$hget(text,t) - Satır,0))
      cvp privmsg $_helpers Toplam atılan IP sayısı: $kp($iif($hget(flood,0).item,$hget(flood,0).item,0))
      cvp privmsg $_helpers -
      cvp privmsg $_helpers $kp($_help) kanal'ı için tüm istatistik'ler sıralandı.
      cvp privmsg $_helpers Bir helper hakkında ayrıntılı bilgi almak için; $kp(!bilgi helper-nick) yazınız.
      cvp privmsg $_helpers Hangi helper, kaç adet ban atmış öğrenmek için; $kp(!banlar) yazınız.
      cvp privmsg $_helpers Hangi helper, kaç adet voice vermiş; $kp(!voicelist) yazınız.
    }
    if $remove($4,$chr(58)) == !hekle && !$6- {

      if $hmatch(helplist,$5) { cvp privmsg $_helpers Bilgi: $kp($5) zaten helper listesinde. | halt }
      else { hadd -m helplist $5 1 | hsave -i helplist helplist.db | cvp privmsg $_helpers Bilgi: $kp($5) helper listesine, başarı ile eklendi. }
    }
    if $remove($4,$chr(58)) == !hsil && !$6- {
      if !$hmatch(helplist,$5) { cvp privmsg $_helpers Bilgi: $kp($5) helper listesinde bulunamadı. | halt }
      else { 
        if $hmatch(helplist,$5) { hdel helplist $5 | hsave -i helplist helplist.db }
        if $hmatch(ygiris,$5) && $hmatch(ygiris,y) { hdec ygiris y $hget(ygiris,$5) | hdel ygiris $5 | hsave -i ygiris ygiris.db }
        if $hmatch(banlar,v) && $hmatch(banlar,$5) { hdec banlar v $hget(banlar,$5) | hdel banlar $5 | hsave -i banlar banlar.db }
        if $hmatch(text,t) && $hmatch(text,$5) { hdec text t $hget(text,$5) | hdel text $5 | hsave -i text text.db }
        if $hmatch(ycıkıs,y) && $hmatch(ycıkıs,$5) { hdec ycıkıs y $hget(ycıkıs,$5) | hdel ycıkıs $5 | hsave -i ycıkıs ycıkıs.db }
        if $hmatch(tvoice,v) && $hmatch(voice,$5) { hdec tvoice v $hget(voice,$5) | hdel voice $5 | hsave -i voice voice.db | hsave -i tvoice tvoice.db }
        if $isfile($+(helper/,$5,.txt)) { remove $+(helper/,$5,.txt) }
        cvp privmsg $_helpers Bilgi: $kp($5) helper listesin'den silindi. 
      }
    }
    if $remove($4,$chr(58)) == !floodip && !$5- {
      if !$hget(flood) { cvp privmsg $_helpers Flood yapan ipler için herhangi bir kayıt yok. | halt }
      else {
        cvp privmsg $_helpers Flood giriş limit'ini aşarak atılan IP'ler sıralanıyor; | cvp privmsg $_helpers Toplam IP kaydı: $kp($hget(flood,0).item)) | cvp privmsg $_helpers -
        var %s = 1,%ss = $hget(flood,0).item
        while %s <= %ss {
          cvp privmsg $_helpers Nick: $kp($hget(flood,%s).data) - IP: $kp($hget(flood,%s).item)
          inc %s
        }
        cvp privmsg $_helpers - | cvp privmsg $_helpers Flood IP kayıtları sıralandı.
        cvp privmsg $_helpers Tüm kayıtları silmek için; $kp(!ipsil) yazınız.
      }
    }
    if $remove($4,$chr(58)) == !ipsil && !$5- {
      if !$isfile(flood.db) { cvp privmsg $_helpers Silinecek herhangi IP kaydı yok. | halt }
      else { cvp privmsg $_helpers Toplam $kp($hget(flood,0).item) adet IP kaydı başarı ile silindi. | remove flood.db | hfree flood }
    }
  }
  if $2 == privmsg && $3 == $_hbot && $remove($4,:) = !destek {
    hinc -mu900 falan $ayr($1) 1 
    if $hget(falan,$ayr($1)) == 1 {
      cvp privmsg $ayr($1) Basit destek dökümanı sıralanıyor. | cvp privmsg $ayr($1) -
      cvp privmsg $ayr($1) Nick'inizi kaydetmek için; $kp(/ns register şifre e-mail@adresi) komutunu uygulayınız.
      cvp privmsg $ayr($1) Kanal kaydetmek için; ilk öncelikle kanal'ın kayıtlı olmadığından emin olun. Ardından kanal'a girerek @op konumuna geçin; ve $kp(/cs register #kanal-adı şifre açıklama) komutunu uygulayın.
      cvp privmsg $ayr($1)  -
      cvp privmsg $ayr($1) Chanserv(kanal servisi) hakkında detaylı bilgi almak için; $kp(/cs help)
      cvp privmsg $ayr($1) Nickserv(rumuzu servisi) hakkında detaylı bilgi almak için; $kp(/ns help)
      cvp privmsg $ayr($1) Memoserv(özel mesaj servisi) hakkında detaylı bilgi almak için; $kp(/ms help)
      cvp privmsg $ayr($1)  -
      cvp privmsg $ayr($1) Diğer komutlar hakkında bilgi almak için; $kp(/helpop ?) yazınız.
    }
    if $hget(falan,$ayr($1)) == 2 { cvp privmsg $ayr($1) :Destek dökümanını zaten $kp(1) kere görüntülediniz. | halt }
    if $hget(falan,$ayr($1)) >= 3 { cvp privmsg $ayr($1) :Gerzek değilim desen bile, davranışların etiket ediyor seni. }
  }
  if $2 == privmsg && $hmatch(helplist,$ayr($1)) && $3 == $_help {
    hinc -m text t 1 | hsave -i text text.db
    if !$hget(text,$ayr($1)) { hadd -m text $ayr($1) 1 | hsave -i text text.db }
    else { hinc -m text $ayr($1) 1 | hsave -i text text.db }
  }
  if $2 == part && $3 == $_help {
    if $isfile($+(helper/,$ayr($1),.txt)) || $hget(helplist,$ayr($1)) {
      write $+(helper/,$ayr($1),.txt) <= Çıkış: $kp($date) - Saat: $kp($time) 
      hinc -m ycıkıs $ayr($1) 1 | hsave -i ycıkıs ycıkıs.db
      hinc -m ycıkıs y 1 | hsave -i ycıkıs ycıkıs.db
    }
    else { if $ayr($1) != $sock(hbot).mark { cvp privmsg $ayr($1) $kp($ayr($1)) $gettok($_sunucu,2-,46) help grup hoş sohbetler diler. } }
  }
}
